Option Explicit
Const CAPICOM_CURRENT_USER_STORE = 2
Const CAPICOM_CERTIFICATE_INCLUDE_WHOLE_CHAIN = 1
Const CAPICOM_ENCODE_ANY = -1
Const CAPICOM_ENCODE_BASE64 = 0
Const CAPICOM_ENCODE_BINARY = 1
Const ForReading = 1

Dim oSigner
Set oSigner = CreateObject("CAdESCOM.CPSigner")
' Укажите правильный серийный номер сертификата.
Dim sSerialNumber : sSerialNumber = "1F6CC24E000200090C3B"
' Укажите правильный адрес службы штампов времени.
Dim sTSAAddress : sTSAAddress = "http://www.cryptopro.ru/tsp/tsp.srf"

oSigner.Certificate = GetSignerCertificate(sSerialNumber)
oSigner.TSAAddress = sTSAAddress
oSigner.Options = CAPICOM_CERTIFICATE_INCLUDE_WHOLE_CHAIN

Dim oSignedData
Set oSignedData = CreateObject("CAdESCOM.CadesSignedData")
oSignedData.Content = LoadFile("test.dat")
Dim sSignedData
sSignedData = oSignedData.Sign(oSigner, True)

Dim oSignedData2
Set oSignedData2 = CreateObject("CAdESCOM.CadesSignedData")
oSignedData2.Content = LoadFile("test.dat")
oSignedData2.Verify sSignedData, True

Function GetSignerCertificate(SerialNumber)
   Set GetSignerCertificate = Nothing
   Dim oCert
   Dim oStore
   Set oStore = CreateObject("CAPICOM.Store")
   oStore.Open CAPICOM_CURRENT_USER_STORE
   For Each oCert In oStore.Certificates
     If oCert.SerialNumber = SerialNumber Then
       Set GetSignerCertificate = oCert
       Exit For
     End If
   Next
End Function

Function LoadFile (FileName)
   Dim fso
   Set fso = CreateObject("Scripting.FileSystemObject")
   If Not fso.FileExists(FileName) Then
     Err.Raise vbObjectError+1, "LoadFile", "File not found"
   End If 
   Dim ts
   Set ts = fso.OpenTextFile(FileName, ForReading)  
   LoadFile = ts.ReadAll
End Function

sSignedData = oSignedData.Sign(oSigner, True)